home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / AMIGA / AMICUS / AMICUS01.ADF / ABasicStuff / Graphics / Cubes.bas < prev    next >
BASIC Source File  |  1985-12-04  |  2KB  |  64 lines
  1. 10    rem 3D CUBES Version 1.0 11/9/85
  2. 12    rem From Atari version - Compute! Magazine
  3. 14    rem Amiga version by R. Grokett
  4. 20    randomize -1
  5. 30    sq%=50
  6. 40    screen 0,4,0
  7. 50    ?"    3D Cubes -- Version 1.0"
  8. 60    ?:?:?:?"Press:"
  9. 70    ?
  10. 80    ?" (S)ize..........Change cube size"
  11. 90    ?" (C)olor.........Change cube color"
  12. 100   ?" <RETURN>........Clear screen"
  13. 110   ?" <ESC>...........Exit from CUBES"
  14. 120   ?:?:?:?:?:?:?:?:?:?:?:?"Press <RETURN> to begin!";
  15. 130   getkey key$
  16. 140   GOSUB 550
  17. 150   scnclr
  18. 160   rgb 0,0,0,0
  19. 170   rgb 1,0,0,0
  20. 180   rgb 2,0,0,0
  21. 190   GOSUB 320
  22. 200   REM MAIN
  23. 210   x%=rnd(1)*320:y%=rnd(1)*200
  24. 250   get key$
  25. 260   IF KEY$="c" THEN GOSUB 320
  26. 270   if key$=chr$(27) then 610
  27. 280   if key$="s" then gosub 540
  28. 290   if key$=chr$(13) then 150
  29. 300   GOSUB 400
  30. 310   GOTO 210
  31. 320   REM COLOR CHANGE
  32. 330   c1%=(rnd(1)*14)+2
  33. 340   c2%=(rnd(1)*14)+2
  34. 350   c3%=(rnd(1)*14)+2
  35. 360   rgb 3,c1%,c2%,c3%
  36. 370   rgb 4,c1%-1,c2%-1,c3%-1
  37. 380   rgb 5,c1%-2,c2%-2,c3%-2
  38. 390   RETURN 
  39. 400   rem PLOT
  40. 410   pena 3
  41. 420   FOR I%=0 TO SQ%
  42. 430   DRAW (x%,y%+i% to X%+SQ%,Y%+I%)
  43. 440   NEXT I%
  44. 450   pena 4
  45. 460   FOR I%=1 TO INT(3*SQ%)/5
  46. 470   draw (X%+I%,Y%-I% TO X%+I%+SQ%,Y%-I%)
  47. 480   NEXT I%
  48. 490   pena 5
  49. 500   FOR I%=1 TO INT(3*SQ%)/5
  50. 510   draw (X%+SQ%+I%,Y%-I% TO X%+SQ%+I%,Y%+SQ%-I%+1)
  51. 520   NEXT I%
  52. 530   RETURN 
  53. 540   REM CUBE SIZE
  54. 550   rem
  55. 560   sq%=sq%-5
  56. 570   IF SQ%<5 then sq%=50
  57. 580   RETURN
  58. 610   rem EXIT
  59. 620   rgb 0,6,9,15
  60. 630   rgb 1,0,0,0
  61. 640   rgb 2,15,15,15
  62. 650   scnclr
  63. 660   end
  64.